gitpatcher/build.gradle at master · MinecraftForge/gitpatcher · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
plugins {
    id 'java-gradle-plugin'
    id 'groovy'

    id 'eclipse'
    id 'idea'

    id 'maven-publish'
    id 'com.gradle.plugin-publish' version '0.15.0'

    id 'org.cadixdev.licenser' version '0.6.1'
    id 'net.minecraftforge.gradleutils' version '1.+'
}

group = 'net.minecraftforge' // Publishing under our name as we are a fork
version = gradleutils.getTagOffsetBranchVersion(null, 'master', 'HEAD')
description = 'A Gradle plugin to manage patches for Git repositories'

sourceCompatibility = '1.7'
targetCompatibility = '1.7'

repositories {
    mavenCentral()
}

tasks.withType(GroovyCompile) {
    groovyOptions.optimizationOptions.indy = true
}

license {
    header = file('LICENSE')
    include '**/*.java'
    include '**/*.groovy'
}

java {
    withSourcesJar()
    withJavadocJar()
}

publishing {
    publications {
        withType(MavenPublication) {
            pom {
                description = project.description
            }
        }
    }
    repositories {
        maven {
            if (System.env.MAVEN_USER) {
                url 'https://maven.minecraftforge.net/releases/'
                authentication {
                    basic(BasicAuthentication)
                }
                credentials {
                    username = System.env.MAVEN_USER ?: 'not'
                    password = System.env.MAVEN_PASSWORD ?: 'set'
                }
            } else {
                url 'file://' + rootProject.file('repo').getAbsolutePath()
            }
        }
    }
}

tasks.named('javadocJar', Jar).configure {
    dependsOn 'groovydoc'
    archiveClassifier = 'groovydoc'
    from groovydoc.destinationDir
}

validatePlugins {
    ignoreFailures = true
    failOnWarning = false // abstract classes should be ok without annotations?
}

gradlePlugin {
    plugins {
        gitpatcherPlugin {
            id = 'net.minecraftforge.gitpatcher'
            implementationClass = 'net.minecrell.gitpatcher.GitPatcher'
            displayName = 'gitpatcher'
            description = project.description
        }
    }
}

pluginBundle {
    website = 'https://github.com/MinecraftForge/gitpatcher'
    vcsUrl = website
    description = project.description
    tags = ['git']
}