command line argument "-window <xpos> <ypos> <xsize> <ysize>" and "open modes" referring to command line options

[kpentzlin]

An additional command line argument like "-window " would allow to specify the window position and size even for documents not opened before (or to specify them independent of prior use of the document).

Based on this, I suggest to implement the possibility of defining some (maybe up to 10) user-specific "open modes". These are combinations of one or more command line options (e.g.: -view "single page" -window 0 0 1200 2100), and they should be added to the context menu of the file types handled by SumatraPDF as "open with SumatraPDF mode ".

This would be especially useful for people use large (e.g. 4K or 6K) monitors or multi-monitor configurations, which want to specify where the displayed files should be shown, especially when some informative PDFs are to be displayed besides the current work (e.g. Word document) displayed in the center of the monitor configuration.

[GitHubRulesOK]

Hmm that is basically external invocation and can be done many ways via Windows own programming languages there are over a handfull but for an example of move Edge see https://github.com/GitHubRulesOK/MyNotes/blob/master/C%23/MoveEdge.cmd

BUT BY FAR THE SIMPLEST is VBS

[kjk]

that sounds like a job for external programs you can use many tools to position windows programmatically. I can't add every flight of fancy feature to sumatra.

[GitHubRulesOK]

@kpentzlin
Use this session placer it is still a work in progress but WORKS for my installations.
The screenshot is via SumatraPDF own screengrabber.
the first case is a Virtual Sandbox, The second illustrates it works with 2 monitors.

Option Explicit
Dim args, settingsFile, presets(), i
Set args = WScript.Arguments
' --- Basic guard: need at least filename + 1 preset ---
If args.Count < 2 Then
    MsgBox "Usage:" & vbCrLf & _
           "  Presets.vbs <settingsfile> <WinPos> [set1] [set2] ..." & vbCrLf & vbCrLf & _
           "Example: note first session is same as master" & vbCrLf & _
           "  Presets.vbs ""d:\ path to \SumatraPDf-settings.txt"" ""1000 0 400 350"" ""1000 0 400 350"" ""1000 350 400 700""", _
           vbExclamation, "Missing Arguments"
    WScript.Quit 1
End If
settingsFile = args(0)
' --- Load presets from command-line ---
ReDim presets(args.Count - 2)
For i = 1 To args.Count - 1
    presets(i - 1) = args(i)
Next
' --- Load file ---
Dim fso, fileIn, fileOut, text, lines
Set fso = CreateObject("Scripting.FileSystemObject")
If Not fso.FileExists(settingsFile) Then
    MsgBox "Settings file not found:" & vbCrLf & settingsFile, vbCritical, "Error"
    WScript.Quit 1
End If
Set fileIn = fso.OpenTextFile(settingsFile, 1, False)
text = fileIn.ReadAll
fileIn.Close
lines = Split(text, vbCrLf)
' --- Replacement logic ---
Dim idx : idx = 0
Dim firstWindowDone : firstWindowDone = False
Dim waitingForSessionWindow : waitingForSessionWindow = False
For i = 0 To UBound(lines)
    Dim raw : raw = lines(i)
    Dim L : L = raw
    ' Strip leading whitespace for matching
    Do While Len(L) > 0 And (Mid(L,1,1) = " " Or Mid(L,1,1) = vbTab)
        L = Mid(L,2)
    Loop
    ' FIRST WindowPos (no indent)
    If Not firstWindowDone Then
        If Left(L, 11) = "WindowPos =" Then
            If idx <= UBound(presets) Then
                lines(i) = "WindowPos = " & presets(idx)
                idx = idx + 1
            End If
            firstWindowDone = True
        End If
    Else
        ' Detect TabIndex
        If Left(L, 10) = "TabIndex =" Then
            waitingForSessionWindow = True
        ' Replace WindowPos after TabIndex (with two tabs)
        ElseIf waitingForSessionWindow And Left(L, 11) = "WindowPos =" Then
            If idx <= UBound(presets) Then
                lines(i) = Chr(9) & Chr(9) & "WindowPos = " & presets(idx)
                idx = idx + 1
            End If
            waitingForSessionWindow = False
        End If
    End If
Next
' --- Write file back ---
text = Join(lines, vbCrLf)
Set fileOut = fso.OpenTextFile(settingsFile, 2, False)
fileOut.Write text
fileOut.Close

The choice of positions is highly custom to each individual usage and thus you may need to experiment a few times but here with 2 monitors the Upper Left has been placed as 2 sessions on far left and the smaller lower right monitor is filled full screen.

Presets.vbs "C:\Users\K\AppData\Local\SumatraPDF\SumatraPDf-settings.txt" "-1920 -292 800 540" "-1920 -832 800 540" "0 0 800 600" "-1920 -292 800 540"